# SPDX-FileCopyrightText: © 2026 Jeffrey C. Ollie <jeff@ocjtech.us>
# SPDX-License-Identifier: MIT

{
  lib,
  stdenv,
  callPackage,
  zig_0_16,
}:
let
  # Generated by zon2nix from build.zig.zon; regenerate with:
  #   nix run github:jcollie/zon2nix#zon2nix -- --nix=build.zig.zon.nix --16 build.zig.zon
  zigDeps = callPackage ../build.zig.zon.nix { };
in
stdenv.mkDerivation {
  pname = "zsmtp";
  version = "0.0.0";

  src = lib.cleanSource ../.;

  nativeBuildInputs = [ zig_0_16 ];

  dontConfigure = true;

  buildPhase = ''
    runHook preBuild
    export ZIG_GLOBAL_CACHE_DIR=$TMPDIR/zig-global-cache
    zig build install -Doptimize=ReleaseSafe --prefix $out --system ${zigDeps}
    runHook postBuild
  '';

  doCheck = true;
  checkPhase = ''
    runHook preCheck
    zig build test --system ${zigDeps}
    runHook postCheck
  '';

  dontInstall = true;

  meta = {
    description = "SMTP client and server library for Zig";
    license = lib.licenses.mit;
    mainProgram = "zsmtp";
  };
}